More Anime Pin-Up Beauties/More Anime Pin-Up Beauties.iso/mac/WEST/GPX04.dir/00194_Script_194

Text File | 1998-06-22 | 8KB | 255 lines

-- Standard Services

-- ++++++++++++++++++++++++++++++++ clear Picture of cast vCast
on clrPicture vCast
    set the picture of cast vCast to the picture of cast "EmptyPict"

-- ++++++++++++++++++++++++++++++++ getText from fileName
on getText fileName
    put FileIO(mNew,"read",fileName) into vText
    if objectp(vText) then
        put vText(mReadFile) into retText
        vText(mDispose)
    else
        put "" into retText
    end if
    return (retText)

-- ++++++++++++++++++++++++++++++++ getPicture from fileName to vCast
on getPicture vCast, vfileName
    put vfileName & ".PIC" into fileName
    if (the name of cast vCast <> "") then
        set nameOfCast to the name of cast vCast
    else
        set nameOfCast to ""
    end if
    put FileIO(mNew,"read",fileName) into vPict
    if (not objectp(vPict)) then
        alert "Error(getPicture):"&fileName&RETURN&"code:"&vPict
        return (FALSE)
    end if
    set the picture of cast vCast to vPict(mReadPict)
    if (the size of cast vCast = 0) then
        clrPicture(vCast)
        set the name of cast vCast to nameOfCast
        unload
        unloadCast
        set the picture of cast vCast to vPict(mReadPict)
        if (the size of cast vCast = 0) then
            clrPicture(vCast)
            set the name of cast vCast to nameOfCast
            vPict(mDispose)
            alert "Error(getPicture):"&fileName&RETURN&"code:"&vPict&RETURN&"Not enough Memory"
            return (FALSE)
        end if
    end if
    vPict(mDispose)
    return(TRUE)

-- ++++++++++++++++++++++++++++++++ set vSprite as Pict for vCast(BitMap) with vInk
on setPictSprite vSprite, vCast, vInk
    if the type of sprite vSprite = 0 then set the type of sprite  vSprite to 1
    puppetSprite vSprite ,TRUE
    set the castNum of sprite vSprite to the number of cast vCast
    set the ink of sprite vSprite to vInk

-- ++++++++++++++++++++++++++++++++ set vSprite as Text vCast(Text) with vInk locate vH vV
on setTextSprite vSprite, vCast, vInk, vH, vV
    if the type of sprite vSprite = 0 then set the type of sprite  vSprite to 7
    puppetSprite vSprite ,TRUE
    set the castNum of sprite vSprite to the number of cast vCast
    set the ink of sprite vSprite to vInk
    set the locH of sprite vSprite to vH
    set the locV of sprite vSprite to vV

-- ++++++++++++++++++++++++++++++++ control button
on pushButton com
    put the locH of sprite clickOn() into vH
                put the locV of sprite clickOn() into vV
    repeat while stilldown()
        if rollover(clickOn()) then
            set the locH of sprite clickOn() to vH + 2
            set the locV of sprite clickOn() to vV + 2
        else
            set the locH of sprite clickOn() to vH
            set the locV of sprite clickOn() to vV
        end if
        upDateStage
    end repeat
    set the locH of sprite clickOn() to vH
    set the locV of sprite clickOn() to vV
    upDateStage
    if rollOver(clickOn()) then do com

-- ++++++++++++++++++++++++++++++++ QTmovie forward to End button
on qtEnd vSprite
    put (the duration of cast (the castNum of sprite vSprite)) into vLen
    set the movieTime of sprite vSprite to vLen - 1
    set the movieRate of sprite vSprite to 0
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie rewind to Top button
on qtTop vSprite
    set the movieTime of sprite vSprite to 0
    set the movieRate of sprite vSprite to 0
    set the startTime of sprite vSprite to 0
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie rewind to vTop button
on XqtTop vSprite, vTop
    set the movieTime of sprite vSprite to vTop
    set the movieRate of sprite vSprite to 0
    set the startTime of sprite vSprite to vTop
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie rewind(10sec) button
on qtRew vSprite
    put the movieTime of sprite vSprite into vTime
    if (vTime > 600) then
        put (vTime - 600) into vTime
    else
        put 0 into vTime
    end if

    set the movieTime of sprite vSprite to vTime
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie rewind(10sec but limit) button
on XqtRew vSprite, vTop
    put the movieTime of sprite vSprite into xTime
    put (xTime - vTop) into vTime
    if (vTime > 600) then
        put (xTime - 600) into vTime
    else
        put vTop into vTime
    end if

    set the movieTime of sprite vSprite to vTime
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie forward(10sec) button
on qtFwd vSprite
    put the movieTime of sprite vSprite into vTime
    put (the duration of cast (the castNum of sprite vSprite)) into vLen
    if ((vLen - vTime)>600) then
        put (vTime + 600) into vTime
    else
        put (vLen - 1) into vTime
    end if

    set the movieTime of sprite vSprite to vTime
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie forward(10sec but limit) button
on XqtFwd vSprite, vEnd
    put the movieTime of sprite vSprite into vTime
    if ((vEnd - vTime)>600) then
        put (vTime + 600) into vTime
    else
        put vEnd into vTime
    end if

    set the movieTime of sprite vSprite to vTime
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie pause button
on qtPau vSprite
    global gAviTime

    if (the movieRate of sprite vSprite = 0) then
        if (the movieTime of sprite vSprite > 0) then
            put the movieTime of sprite vSprite into gAviTime
            set the movieRate of sprite vSprite to 1
        end if

    else
        set the movieRate of sprite vSprite to 0
    end if

    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie Stop button
on qtStp vSprite
    set the movieRate of sprite vSprite to 0
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie play button
on qtPly vSprite
    set the movieRate of sprite vSprite to 1
    upDateStage

-- ++++++++++++++++++++++++++++++++ QTmovie yalp(reverse play) button
on qtYlp vSprite
    set the movieRate of sprite vSprite to -1
    updateStage

-- ++++++++++++++++++++++++++++++++ QTmovie sound toggle
on qtSoundToggle
    if the sound of cast (the castNum of sprite clickOn()) = TRUE then
        set the sound of cast (the castNum of sprite clickOn()) = FALSE
    else
        set the sound of cast (the castNum of sprite clickOn()) = TRUE
    end if

-- ++++++++++++++++++++++++++++++++ AIFF sound file control in soundchannel 2
on aiffSound vNum
    global gPathAiff
    global gBgmNum
    if the soundEnabled = FALSE then
        return
    end if

    if vNum = 0 then
            if soundBusy(1) then
                sound stop 1
            end if

        put 0 into gBgmNum
    else
        if soundBusy(1) AND gBgmNum = vNum then
            return
        end if

        sound playFile 1, gPathAiff & "BGM0" & string(vNum) & ".AIF"
        put vNum into gBgmNum
    end if

-- Fade out other channel
on aiffFadeOut vNum
    repeat with n = 1 to 4
        if  (vNum <> n) then
            if soundBusy(n) then
                sound fadeOut n, 60
            end if
        end if
    end repeat

-- wait click (or vTim seconds)
on clickWait vTim
    startTimer
    repeat while TRUE
        if (the timer > (vTim*60)) then
            exit repeat
        end if
        if (the mouseDown) then return(FALSE)
    end repeat
    return(TRUE)

--+++++++++++++++++++++++++++++++++ Palette change at black frame
on chgScene vPal, vFrm, vBackName
    global gFulCol
    global gCurPal

    --if (gFulCol = 0) and (gCurPal <> vPal) then
    --    go to frame "PALCHN"
    --end if

    put vPal into gCurPal
    puppetPalette vPal
    puppetTransition 23
    upDateStage
    getPicture(the number of cast "BCK.PICT", vBackName)
    puppetTransition 23
    go to frame vFrm
    upDateStage